{ pkgs, inputs, config, lib, ... }:
let
  username = "media";
  pubKeys = lib.filesystem.listFilesRecursive (../keys);
  hostname = config.networking.hostName;
  sopsHashedPasswordFile = lib.optionalString (lib.hasAttr "sops-nix" inputs) config.sops.secrets."passwords/${username}".path;
  secretsDirectory = builtins.toString inputs.nix-secrets;
  secretsFile = "${secretsDirectory}/secrets.yaml";

in 
{
  users.users.${username} = {
    isNormalUser = true;
    shell = pkgs.zsh; # default shell
    hashedPasswordFile = sopsHashedPasswordFile;
    openssh.authorizedKeys.keys = lib.lists.forEach pubKeys (key: builtins.readFile key);

    extraGroups =
       [ "qemu-libvirtd" "libvirtd" 
         "wheel" "video" "audio" "disk" "networkmanager" 
       ]; 

    packages = with pkgs; [
      flatpak
      gnome.gnome-software
    ];
  };

  environment.persistence."/persist" = {
    hideMounts = true;
    users.${username}= {
        directories = [
          "sync"
          "keep"
          ".ssh"
          ".config/dconf"
          ".config/cinnamon"
          ".config/nemo"
	        ".mozilla"
	        ".local"
        ];
        files = [
        ];
    };
  };

  sops.secrets = {
    "passwords/${username}" = {
      sopsFile = "${secretsFile}";
      neededForUsers = true;
    };
    "ssh_keys/${username}/id_ed25519" = {
      path = "/home/${username}/.ssh/id_ed25519";
      mode = "0600";
      owner = "${username}";
      };
    "ssh_keys/${username}/id_ed25519.pub" = {
      path = "/home/${username}/.ssh/id_ed25519.pub";
      mode = "0644";
      owner = "${username}";
    };
  };

  services.flatpak.enable = true;

  programs.zsh.enable = true;
  programs.fuse.userAllowOther = true;

  home-manager = {
    extraSpecialArgs = { inherit inputs; };
    users = {
      ${username} = import ../../../../home/${hostname}.nix;
    };
  };
}